SO3Engine/SCOLBasic/Cpuid.cpp

Go to the documentation of this file.

#include "Cpuid.h"



__declspec(naked) int __stdcall CpuInfo(PCPUINFOS pcpuinf)
{
        __asm {
                push    ebx
                        xor     eax, eax
                        cpuid
                        test    eax, eax
                        mov     eax, [esp+8]
                jne     short cpuidOK  ; PAS BON ON SORT
                        pop     ebx
                        ret     4
cpuidOK:
                push    ebp
                        push    edi
                        mov     ebp, [eax]     ; EBP = *pszVendorId
                        mov     edi, eax       ; EDI = pcpuinf
                        test    ebp, ebp
                        jz      short GO_CpuName
                        xor     eax, eax
                        mov     [ebp], ebx
                        mov     [ebp+4], edx
                        mov     [ebp+8], ecx
                        mov     dword ptr[ebp+12], eax
GO_CpuName:
                mov     ebp, [edi+4]   ; EBP = pszCpuName
                        mov     eax, 80000000h
                        test    ebp, ebp
                        jz      short GO_EAX1
                        cpuid
                        xor     edx, edx
                        cmp     eax, 80000004h
                        jae     short cpunameOK
                        mov     [ebp], edx
                        jmp     short GO_EAX1
cpunameOK:
                mov     eax, 80000002h
                        cpuid                  ; 1ere PASSE
                        mov     [ebp], eax
                        mov     [ebp+4], ebx
                        mov     [ebp+8], ecx
                        mov     [ebp+12], edx
                        mov     eax, 80000003h
                        add     ebp, 16
                        cpuid                  ; 2eme PASSE
                        mov     [ebp], eax
                        mov     [ebp+4], ebx
                        mov     [ebp+8], ecx
                        mov     [ebp+12], edx
                        mov     eax, 80000004h
                        add     ebp, 16
                        cpuid                  ; 3eme PASSE
                        mov     [ebp+4], ebx
                        mov     [ebp+12], edx
                        lea     ebx, [ebp-32]
                mov     [ebp], eax
                        lea     edx, [ebx-1]
                mov     [ebp+8], ecx
trimL:
                inc     edx
                        cmp     byte ptr[edx], 32
                        je      short trimL
                        cmp     edx, ebx
                        je      short GO_EAX1 ; PAS DE TRIML A FAIRE
goName:
                mov     al, [edx]
                mov     [ebx], al
                        inc     edx
                        inc     ebx
                        test    al, al
                        jne     short goName
GO_EAX1:
                mov     eax, 1
                        cpuid
                        mov     edx, eax
                        shr     ebx, 16
                        mov     ecx, eax
                        and     edx, 0Fh
                        test    bl, bl
                        jne     short countOK
                        inc     bl
countOK:
                shr     eax, 4
                        mov     [edi+8], bl    ; CountOfLogicalProcessors
                        mov     [edi+11], dl   ; SteppingID
                        and     ecx, 0F00h
                        and     eax, 0Fh
                        mov     [edi+9], ch    ; FamilyCode
                        mov     [edi+10], al   ; ModelNumber
infoExit:
                pop     edi
                        pop     ebp
                        pop     ebx
                        ret     4
        }
}

---