mkapplet.pkg

Go to the documentation of this file.

// -- processed by [filterPKG] --
/*
-----------------------------------------------------------------------------
This source file is part of OpenSpace3D
For the latest info, see http://www.openspace3d.com

Copyright (c) 2009 I-maginer

This program is free software; you can redistribute it and/or modify it under
the terms of the GNU Lesser General Public License as published by the Free Software
Foundation; either version 2 of the License, or (at your option) any later
version.

This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public License along with
this program; if not, write to the Free Software Foundation, Inc., 59 Temple
Place - Suite 330, Boston, MA 02111-1307, USA, or go to
http://www.gnu.org/copyleft/lesser.txt

You may alternatively use this source under the terms of a specific version of
the OpenSpace3D Unrestricted License provided you have obtained such a license from
I-maginer.
-----------------------------------------------------------------------------
*/

/*
applet file generator
origin by Sylvain Huet - oct 2003

Bastien Bourineau - june 2009
*/

struct FtpSetting{

  AFTP_telnet (TELNET);
  AFTP_trmTimeout (Timer);
  AFTP_sDataCmd (S);
  AFTP_sIp (S);
  AFTP_sHost (S);
  AFTP_iport (I);
  AFTP_sLogin (S);
  AFTP_sPass (S);
  AFTP_sDir (S);
  AFTP_sAppDir (S);
  AFTP_sUrl (S);
  AFTP_bWebIn (I);
  AFTP_iWidth (I);
  AFTP_iHeight (I);
  AFTP_lFiles ([S r1]);
  AFTP_lDirs ([S r1]);
  
  AFTP_ctrlWindow (EdWindow);
  AFTP_ctrlHost (EdControl);
  AFTP_ctrlPort (EdControl);
  AFTP_ctrlLogin (EdControl);
  AFTP_ctrlPass (EdControl);
  AFTP_ctrlRoot (EdControl);
  AFTP_ctrlDir (EdControl);
  AFTP_ctrlWww (EdControl);
  AFTP_ctrlInWeb (EdControl);
  
  AFTP_ctrlLog (EdControl);
  AFTP_ctrlOk (EdControl);
  AFTP_ctrlCancel (EdControl
  
  );
};
typedef struct mkFtpSetting FtpSetting;


var sMkAppletPath="tools/os3dlib/res/web/";
var sMkAppletTmpPath="tmp/mkapplet/";

typeof winMkApplet=EdWindow;

var iTimeOut=60000;
var iTimeOutCmd=10000;

proto sendFtpCommand=fun[FtpSetting S] I;
proto ftpConnect=fun[FtpSetting] I;

/* ********************************************************************************************* /
  FTP Functions
/ ********************************************************************************************* */


mkAppletEnableInterface(ftpstr, mode){
setEdCtrlButtonEnable ftpstr.AFTP_ctrlOk mode;
  setEdCtrlTextLineEnable ftpstr.AFTP_ctrlHost mode;
  setEdCtrlFloatEnable ftpstr.AFTP_ctrlPort mode;
  setEdCtrlTextLineEnable ftpstr.AFTP_ctrlLogin mode;
  setEdCtrlTextLineEnable ftpstr.AFTP_ctrlPass mode;
  setEdCtrlTextLineEnable ftpstr.AFTP_ctrlRoot mode;
  setEdCtrlTextLineEnable ftpstr.AFTP_ctrlDir mode;
  setEdCtrlTextLineEnable ftpstr.AFTP_ctrlWww mode;
  setEdCtrlCheckEnable ftpstr.AFTP_ctrlInWeb mode;
  0;
}


mkAppletAddLog(ftpstr, message){
let getEdCtrlTextValue ftpstr.AFTP_ctrlLog -> cont in
  let strextr cont -> lines in
  let sizelist lines -> nblines in
  let if nblines >= 50 then strbuild tl lines else cont -> cont in
    setEdCtrlTextValue ftpstr.AFTP_ctrlLog strcatn cont::message::"\n"::nil;
  
  let _GETlineCount getEdCtrlText ftpstr.AFTP_ctrlLog -> lines in
    _SCROLLtext getEdCtrlText ftpstr.AFTP_ctrlLog 0 lines;
  0;
}


cbDlgTimeout(dlg, ftpstr, res){
if res == 1 then
    ftpConnect ftpstr
  else 
  (
    mkAppletAddLog ftpstr "Connection closed.";
    mkAppletEnableInterface ftpstr 1;
    0;
  );
  0;
}


cbMkAppletTimeOut(timer, ftpstr){
_deltimer timer;
  _TELNETClose ftpstr.AFTP_telnet;
  let _DLGMessageBox _channel ftpstr.AFTP_ctrlWindow.EDW_win "Time Out" "Connection failed, retry ?" 1 -> dlgTimeOut in
    _DLGrflmessage dlgTimeOut @cbDlgTimeout ftpstr;
  0;
}


cbTimeOutCmd(timer, ftpstr){
_deltimer timer;
  _TELNETClose ftpstr.AFTP_telnet;
  mkAppletAddLog ftpstr ">> Try to connect.";
  ftpConnect ftpstr;
  0;
}
  

sendFtpCommand(ftpstr, cmd){
if (strfind "LIST" cmd 0)!=nil || (strfind "NLST" cmd 0)!=nil || (strfind "STOR" cmd 0)!=nil || (strfind "RETR" cmd 0)!=nil then
  (
    set ftpstr.AFTP_sDataCmd = cmd;
    mkAppletAddLog ftpstr ">> PASV";
    _TELNETSend "PASV\n" ftpstr.AFTP_telnet;
    0;
  )
  else
  (
    mkAppletAddLog ftpstr strcat ">> " cmd;
    _TELNETSend cmd ftpstr.AFTP_telnet; 
    0; 
  );
  
  set ftpstr.AFTP_trmTimeout = _starttimer _channel iTimeOutCmd;
  _rfltimer ftpstr.AFTP_trmTimeout @cbTimeOutCmd ftpstr;
  0;
}


cbDataTimer(t, data){
_deltimer t;
  _TELNETClose data;
  0;
}


cbDataWrite(data, ftpstr){
if (strfind "STOR" ftpstr.AFTP_sDataCmd 0)!=nil then
  (
    let (hd ftpstr.AFTP_lFiles) -> file in
    (
      mkAppletAddLog ftpstr strcat ">> data upload : " file;
      _TELNETSend (_getpack _checkpack (strcat sMkAppletTmpPath file)) data;
      set ftpstr.AFTP_lFiles = tl ftpstr.AFTP_lFiles;
    );
    
    // il manque parfois un octet le timer va permetre de lui laisser le temps d'envoyer
    let _starttimer _channel 500 -> datatimer in
      _rfltimer datatimer @cbDataTimer data;
    0;
  )
  else
  (
    _TELNETClose data;
    0;
  );
  0;
}


cbDataRead(data, ftpstr){
let _TELNETGetBuffer data -> ftpecho in
    mkAppletAddLog ftpstr ftpecho;
  _TELNETClose data;
  0;
}


cbDataConnect(ftpdata, ftpstr){
//_SETtext output strcatn (_GETtext output)::"\n"::">> connected data"::"\n"::nil;
  _TELNETrflRead ftpdata @cbDataRead ftpstr;
  _TELNETrflWrite ftpdata @cbDataWrite ftpstr;
  //_SETtext output strcatn (_GETtext output)::">> "::cmd::"\n"::nil; 
  _TELNETSend ftpstr.AFTP_sDataCmd ftpstr.AFTP_telnet;
  0;
}


cbDataClose(ftpdata, ftpstr){
mkAppletAddLog ftpstr ">> upload successfull.";
  0;
}


// se connecte au port ftp data
tryToConnectData(serveur, ftpstr){
let _TELNETConnect _channel serveur -> telnetdata in
  (
    mkAppletAddLog ftpstr strcat ">> Connecting on : " serveur;
    _TELNETrflConnect telnetdata @cbDataConnect ftpstr;
    _TELNETrflClose telnetdata @cbDataClose ftpstr;
  );
  0;
}


getPort(str, portpos, pos){
let strfind "," str pos -> npos in
    if npos==nil then 
      (
        let substr str pos ((strfind ")" str 0) - pos) -> port in
        let substr str portpos ((pos -1) - portpos) -> coef in
          (
            _fooS strcat ">>>>>>> coef : " coef;
            _fooS strcat ">>>>>>> port : " port;
            itoa ((atoi coef)*256+(atoi port));
          );
      )
    else
      getPort str pos npos+1
  ;
}


cbMkAppletOpenBrowser(dlg, ftpstr, rep){
if rep then
  (
    let strcatn ftpstr.AFTP_sUrl::"web/index.php"::nil -> url in
      _openbrowserhttp url;
  )
  else nil;
  
  _TELNETClose ftpstr.AFTP_telnet;
  dsEdWindow winMkApplet;
  set winMkApplet = nil;
  0;
}


getFtpResponse(ftpEcho, ftpstr){
let strextr ftpEcho -> echolist in
  let if (sizelist echolist) > 1 then 
        atoi (hd (nth_list echolist ((sizelist echolist)-1)))
      else 
        atoi (hd hd echolist)
  -> cmdid in
//let atoi substr ftpEcho 0 3 -> cmdid in
  if cmdid == 330 then
  (
    // please log in
    sendFtpCommand ftpstr (strcatn "USER "::ftpstr.AFTP_sLogin::"\n"::nil);
  )
  else
  if cmdid == 220 then
  (
    // ready
    sendFtpCommand ftpstr (strcatn "USER "::ftpstr.AFTP_sLogin::"\n"::nil);
  )
  else if cmdid == 331 then
  (
    // transfert complete
    sendFtpCommand ftpstr (strcatn "PASS "::ftpstr.AFTP_sPass::"\n"::nil);
  )
   else if cmdid == 230 then
  (
    // logged in
    sendFtpCommand ftpstr (strcatn "SYST\n"::nil);
  )
  else if cmdid == 215 then
  (
    // System type
    sendFtpCommand ftpstr "TYPE I\n";
  )
  else if cmdid == 200 then
  (
    // TYPE ok
    sendFtpCommand ftpstr (strcatn "CWD "::ftpstr.AFTP_sDir::"\n"::nil);
  )
 /* else if cmdid == 250 then
    (
      // CWD successful
      sendFtpCommand ftpstr "LIST\n";
    )
 */
  // upload
  else if cmdid == 250 || cmdid == 226 || cmdid == 257 || cmdid == 550 || cmdid == 521 then
  (
    // MDK ok or exist transfert complete
    // nextCommmand
    if ftpstr.AFTP_lDirs != nil then 
    (
      sendFtpCommand ftpstr strcatn "MKD "::(hd ftpstr.AFTP_lDirs)::"\n"::nil;
      set ftpstr.AFTP_lDirs = tl ftpstr.AFTP_lDirs;
      0;
    )
    else if ftpstr.AFTP_lFiles != nil then 
    (
      //let if (hd ftpstr.AFTP_lFiles) == nil then (hd tl ftpstr.AFTP_lFiles) else (hd ftpstr.AFTP_lFiles) -> fileok in
      sendFtpCommand ftpstr strcatn "STOR "::((hd ftpstr.AFTP_lFiles))::"\n"::nil;
      0;
    )
    else
    (
      sendFtpCommand ftpstr "QUIT\n";
      0;
    );
    0;
  )
  else if cmdid == 227 then
  (
    // pasv
    tryToConnectData (strcatn ftpstr.AFTP_sIp::":"::(getPort ftpEcho 0 0)::nil) ftpstr;
  )
  else if cmdid == 421 then
  (
    // time out
    _DLGMessageBox _channel ftpstr.AFTP_ctrlWindow.EDW_win "Time Out" "You have been disconnected from the server" 0;
    mkAppletEnableInterface ftpstr 1;
    0;
  )
  else if cmdid == 221 then
  (
    // Quit
    let strcatn ftpstr.AFTP_sUrl::"web/index.php"::nil -> url in
      _DLGrflmessage _DLGMessageBox _channel ftpstr.AFTP_ctrlWindow.EDW_win "Upload finished" (strcat "Upload finished. Do you want to open the web page ? " url) 1 @cbMkAppletOpenBrowser ftpstr;
    0;
  )
  else if cmdid == 530 then
  (
    // bad login
    mkAppletAddLog ftpstr "Bad login or password.";
    _TELNETClose ftpstr.AFTP_telnet; 
    mkAppletEnableInterface ftpstr 1;
    0;
  )
  else if cmdid == 150 then
  (
    mkAppletAddLog ftpstr "Transfer in progress ...";
    0;
  )
  else nil;   
  0;
}


cbTelnetWrite(tel, ftpstr){
mkAppletAddLog ftpstr ">> server ready.";
  0;
}


cbTelnetRead(tel, ftpstr){
let _TELNETGetBuffer tel -> ftpecho in
  (
    _deltimer ftpstr.AFTP_trmTimeout;
    mkAppletAddLog ftpstr ftpecho;

    getFtpResponse ftpecho ftpstr;
  );
  0;
}


cbTelnetConnect(tel, ftpstr){
mkAppletAddLog ftpstr ">> Connected.";
  _TELNETrflRead tel @cbTelnetRead ftpstr;
  _TELNETrflWrite tel @cbTelnetWrite ftpstr;
  0;
}


ftpConnect(ftpstr){
let (_gethostbyname ftpstr.AFTP_sHost) -> resolvip in
  let (strcatn resolvip::":"::(itoa ftpstr.AFTP_iport)::nil) -> ftpadress in
  let _TELNETConnect _channel ftpadress -> telnetftp in
  (
    set ftpstr.AFTP_telnet = telnetftp;
    set ftpstr.AFTP_sIp = resolvip;
    mkAppletAddLog ftpstr strcatn ">> Connecting on "::ftpstr.AFTP_sHost::" FTP server."::nil;
    
    set ftpstr.AFTP_trmTimeout = _starttimer _channel iTimeOut;
    _rfltimer ftpstr.AFTP_trmTimeout @cbMkAppletTimeOut ftpstr;
    _TELNETrflConnect ftpstr.AFTP_telnet @cbTelnetConnect ftpstr;
  );
  0;
}


addDirToList(l, ftpstr){
if l == nil then nil else
  let l -> [elem next] in
  (
    set ftpstr.AFTP_lDirs = elem::ftpstr.AFTP_lDirs;
    addDirToList next ftpstr;
  );
  0;
}


getInitDirs(initdir, ftpstr){
let 0 -> curpos in
  let nil -> newldir in
  let (strfind "/" initdir curpos) -> dirpos in
  (
    while dirpos != nil do
    (
      let (strfind "/" initdir (dirpos +1)) -> nextpos in
      let substr initdir curpos ((dirpos) - curpos) -> newdir in
      (
        if (isStringInList ftpstr.AFTP_lDirs (strlowercase newdir)) then nil else 
          set newldir = (strlowercase newdir)::newldir;
      );
      set dirpos = (strfind "/" initdir dirpos +1);
    );
    addDirToList newldir ftpstr;
  );
  0;
}


mkAppletGetDirectories(l){
let sizelist l -> size in
  let nil -> ndata in
  let 0 -> i in
  (
    while i < size do
    (
      let nth_list l i -> elem in
      let getPathFile elem "" -> [path _] in
        set ndata = path::ndata;
        
      set i = i + 1;
    );
    ndata;
  );
}

/*
debugStringList(l, file){
let sizelist l -> size in
  let "" -> ndata in
  let 0 -> i in
  (
    while i < size do
    (
      let nth_list l i -> elem in
        set ndata = strcatn ndata::elem::"\n"::nil;
      set i = i + 1;
    );
    _storepack ndata file;
  );
}
*/

mkAppletUploadFiles(ftpstr){
apply_on_list (mkAppletGetDirectories ftpstr.AFTP_lFiles) @getInitDirs ftpstr;
  // sort list by alphabetical order
  set ftpstr.AFTP_lDirs = sortlist ftpstr.AFTP_lDirs @isSmaller;
  //debugStringList ftpstr.AFTP_lFiles strcat sMkAppletTmpPath "debug.txt";
  
  ftpConnect ftpstr;
  0;
}


/* ********************************************************************************************* /
  Make Applet files
/ ********************************************************************************************* */
mkAppletCpWebfiles(l, path){
if l == nil then nil else
  (
    let getPathFile (hd l) "" -> [_ filename] in
    if !strcmpi "conf.inc.php" filename then nil else
    let _getpack (_checkpack (hd l)) -> fileCont in
      _storepack fileCont (strcatn path::"web/"::filename::nil);
    mkAppletCpWebfiles (tl l) path;
  );
  0;
}


mkAppletPhpInc(ftpstr, filename){
let if ftpstr.AFTP_sAppDir == nil then sMkAppletTmpPath else strcatn sMkAppletTmpPath::ftpstr.AFTP_sAppDir::"/"::nil -> tmppath in
  let _listoffiles sMkAppletPath -> lwebfiles in
  (
    mkAppletCpWebfiles lwebfiles tmppath;
    let strcatn "scol://applet?app="::ftpstr.AFTP_sUrl::filename::nil -> appurl in
    let strcatn "scol://applet:"::ftpstr.AFTP_sUrl::filename::nil -> oldappurl in
    let getVoyagerVersionS -> svoyver in
    _storepack strcatn
    "<?php
    
    $SCOL_SITE_URL = \""::appurl::"\";
    $SCOL_SITE_URL_OLD = \""::oldappurl::"\";
    
    $WIN_32_PLUGIN_URL = \"http://www.scolring.org/rsc/scol_plugin.exe\";
    $MAC_BIN_PLUGIN_URL = \"http://www.scolring.org/rsc/scol_mac.bin\";
    
    //$N6_SCOL_PLUGIN_URL = \"http://www.scolring.org/rsc/npscol.xpi\";
    //$IE_SCOL_PLUGIN_URL = \"http://www.scolring.org/rsc/NewATLScol.dll\";
    
    $LINUX_PLUGIN_URL = \"http://www.scolring.org\";
    $UNKNOWN_PLUGIN_URL = \"http://www.scolring.org\";
    
    $MINIMUMSCOLVERSION = "::svoyver::";
    
    $WEBINTEGRATED = "::(itoa ftpstr.AFTP_bWebIn)::";
    $WIDTH = "::(itoa ftpstr.AFTP_iWidth)::";
    $HEIGHT = "::(itoa ftpstr.AFTP_iHeight)::";
    
    ?>"::nil strcatn tmppath::"web/conf.inc.php"::nil;

    let sizelist lwebfiles -> size in
    let nil -> ndata in
    let 0 -> i in
    (
      while i < size do
      (
        let nth_list lwebfiles i -> elem in
        let getPathFile elem "" -> [_ wname] in
          set ndata = (strcatn ftpstr.AFTP_sAppDir::"/web/"::wname::nil)::ndata;
          
        set i = i + 1;
      );
      (strcat ftpstr.AFTP_sAppDir "/web/conf.inc.php")::ndata;
    );
  );
}


strright(s, i){
substr s (strlen s)-i i;
}


mkAppletFilter(l, path){
if l==nil then nil else
  let if path == nil then sMkAppletTmpPath else strcatn sMkAppletTmpPath::path::"/"::nil -> tmppath in
  let l->[x nxt] in
  let x->[url [name[size[type[sgn _]]]]] in
    if url!=nil && ((!strcmp "http://" substr url 0 7) || (!strcmp "ftp://" substr url 0 6)) then
    let _getpack _checkpack name -> content in
    let zip content -> zipfile in
    (
      _storepack zipfile strcatn tmppath::name::".zp"::nil;
      ((if !strcmpi strright url 3 ".zp" then url else strcat url ".zp")::name::(itoa strlen zipfile)::"2"::(_getlongname content "" "#")::nil)::(mkAppletFilter nxt path);
    )
    else
      x::(mkAppletFilter nxt path);
}


mkAppletCrypt(ftpstr, name, cont, lfiles){
let if (ftpstr.AFTP_sAppDir == nil) then name else strcatn ftpstr.AFTP_sAppDir::"/"::name::nil -> destfile in
  let strbuild mkAppletFilter strextr cont ftpstr.AFTP_sAppDir -> newcontent in
  (
    _storepack newcontent strcat sMkAppletTmpPath destfile;
    
    let mkAppletPhpInc ftpstr name -> lwebfiles in
    let listLowercase (destfile::(lcat lwebfiles lfiles)) -> lupfiles in
      set ftpstr.AFTP_lFiles = lupfiles;
    
    mkAppletUploadFiles ftpstr;
  );
  0;
}


fileExist(l, file){
if l ==nil then 0 else
  if (!strcmp (hd l) file) then 
    1
  else fileExist (tl l) file;
}


findExcluFile(lfiles){
let sizelist lfiles -> size in
  let nil -> nlist in
  let 0 -> i in
  (
    while i < size do
    (
      let nth_list lfiles i -> file in
      let getFileExt file -> ext in 
        if (!strcmpi "bak" ext) || 
          (!strcmpi "scol" ext) ||
          (!strcmpi "max" ext) ||
          (!strcmpi "psd" ext) ||
          (!strcmpi "exe" ext) ||
          (!strcmpi "php" ext) ||
          (!strcmpi "db" ext) ||
          (fileExist nlist file)
        then nil else
      set nlist = file::nlist;
      
      set i = i + 1;
    );
    nlist;
  );
}


// get default player lib and plugin resources
getMkAppletXmlResources(xmlpath){
let XMLload xmlpath -> xmlscenestr in
  let XMLgetMarksByValue xmlscenestr "resource" -> lresourcemarks in
  let XMLgetMarksByValueAndParamValue xmlscenestr "param" "name" "path" -> lparams in
  let XMLgetMarksByValue xmlscenestr "plugin" -> lpluginsmarks in
  let nil -> lout in
  (
    let sizelist lresourcemarks -> size in
    let 0 -> i in
    while i < size do
    (
      let nth_list lresourcemarks i -> resourcemark in
      let XMLgetParam resourcemark "type" -> type in
      let XMLgetParam resourcemark "path" -> path in
        set lout = path::lout;
      
      set i = i + 1;
    );
    
    let sizelist lpluginsmarks -> size in
    let 0 -> i in
    while i < size do
    (
      let nth_list lpluginsmarks i -> pluginmark in
      let strcat "tools/os3dplugins/" XMLgetParam pluginmark "source" -> source in
      let getPathFile source "" -> [plugdir _] in
      let XMLload source -> xmlpluginstr in
      let XMLgetMarkByValue xmlpluginstr "resource" -> resourcemark in
      let XMLgetMarksByValueFromMark resourcemark "file" -> lfilemarks in 
      let XMLgetMarkByValue xmlpluginstr "client" -> clientmark in
      let XMLgetMarksByValueFromMark clientmark "script" -> lscripmarks in
      (
        set lout = source::lout;
        
        let sizelist lfilemarks -> size in
        let 0 -> i2 in
        while i2 < size do
        (
          let nth_list lfilemarks i2 -> filemark in
          let getRelativePath (getDirectoryWithoutLastSlash plugdir) (XMLgetParam filemark "path") -> file in
            set lout = file::lout;
          set i2 = i2 + 1;
        );
        
        let sizelist lscripmarks -> size in
        let 0 -> i2 in
        while i2 < size do
        (
          let nth_list lscripmarks i2 -> scriptmark in
          let getRelativePath (getDirectoryWithoutLastSlash plugdir) (XMLgetParam scriptmark "path") -> file in
            set lout = file::lout;
          set i2 = i2 + 1;
        );
      );
      
      set i = i + 1;
    );
    
    let sizelist lparams -> size in
    let 0 -> i in
    while i < size do
    (
      let nth_list lparams i -> parammark in
      let XMLgetData parammark -> path in
      if (!strcmp "" strtrim path) || path == nil then nil else
        set lout = path::lout;
      
      set i = i + 1;
    );
    
    xmlpath::lout;
  );
}


mkAppletAddFile(url, l, ls){
if l ==nil then ls else 
  let l -> [elem next] in
  (
    let (strcatn url::elem::"\ "::elem::"\n"::ls::nil) -> newstring in
    mkAppletAddFile url next newstring;
  );
}


mkAppletUpdateZpFilesName(l, path){
let if path == nil then "" else strcatn path::"/"::nil -> tmppath in
  let sizelist l -> size in
  let nil -> ndata in
  let 0 -> i in
  (
    while i < size do
    (
      let nth_list l i -> elem in
        set ndata = (strcatn tmppath::elem::".zp"::nil)::ndata;
        
      set i = i + 1;
    );
    ndata;
  );
}


mkAppletGetFilesMd5(lfiles){
let sizelist lfiles -> size in
  let nil -> ndata in
  let 0 -> i in
  (
    while i < size do
    (
      let nth_list lfiles i -> elem in
      let _filemd5 _checkpack elem -> fmd5 in
      if fmd5 == nil then nil else
        set ndata = fmd5::ndata;
      
      set i = i + 1;
    );
    ndata;
  );
}


mkAppletListFiles(xmlpath){
let getFilesFromDirRecursive "tools/os3dlib" -> lib in
  let getFilesFromDirRecursive "tools/os3dplayer" -> player in
  let getMkAppletXmlResources xmlpath -> lres in
    listLowercase findExcluFile (lcat (lcat lib player) lres);
}


mkAppletGetAppMd5(xmlpath){
mkAppletGetFilesMd5 mkAppletListFiles xmlpath;
}


cbMkAppletOkBtn(ctrlbtn, p){
let p -> [xmlpath script ftpstr] in
  let getDirectoryWithoutLastSlash (getEdCtrlTextLineValue ftpstr.AFTP_ctrlWww) -> www in
  let getDirectoryWithoutFirstSlash getDirectoryWithoutLastSlash (getEdCtrlTextLineValue ftpstr.AFTP_ctrlDir) -> appdir in
  let if (!strcmpi "" (strtrim appdir)) then nil else strlowercase appdir -> appdir in
  let getDirectoryWithoutLastSlash (getEdCtrlTextLineValue ftpstr.AFTP_ctrlRoot) -> ftproot in
  let if !strcmp (strtrim ftproot) "" then "/" else (strcat ftproot "/") -> ftproot in
  let (getEdCtrlTextLineValue ftpstr.AFTP_ctrlHost) -> ftphost in
  let ftoi (getEdCtrlFloatValue ftpstr.AFTP_ctrlPort) -> ftpport in
  let (getEdCtrlTextLineValue ftpstr.AFTP_ctrlLogin) -> ftplogin in
  let (getEdCtrlTextLineValue ftpstr.AFTP_ctrlPass) -> ftppass in
  let (getEdCtrlCheckState ftpstr.AFTP_ctrlInWeb) -> webin in
  let if appdir == nil then
        strcatn (if (!strcmp "http://" substr www 0 7) || (!strcmp "https://" substr www 0 7) then nil else "http://")::www::"/"::nil
      else
        strcatn (if (!strcmp "http://" substr www 0 7) || (!strcmp "https://" substr www 0 7) then nil else "http://")::www::"/"::appdir::"/"::nil
  -> url in
  if (!strcmp (strtrim ftphost) "") || (ftpport == nil) || (!strcmp (strtrim ftplogin) "") || (!strcmp (strtrim ftppass) "") || (!strcmp (strtrim www) "") then
  (
    _DLGMessageBox _channel ftpstr.AFTP_ctrlWindow.EDW_win "Error" "Please check the form" 0;
    0;
  )
  else
  (
    set ftpstr.AFTP_sHost = ftphost;
    set ftpstr.AFTP_iport = ftpport;
    set ftpstr.AFTP_sLogin = ftplogin;
    set ftpstr.AFTP_sPass = ftppass;
    set ftpstr.AFTP_sDir = ftproot;
    set ftpstr.AFTP_sAppDir = appdir;
    set ftpstr.AFTP_sUrl = url;
    set ftpstr.AFTP_bWebIn = webin;
    
    setEdCtrlTextValue ftpstr.AFTP_ctrlLog "";
    mkAppletEnableInterface ftpstr 0;
    
    let getFileNameWithoutExt xmlpath -> fname in
    let mkAppletListFiles xmlpath -> lfiles in
    let strcatn (mkAppletAddFile url lfiles nil)::"\nscript\n"::script::nil -> cont in
      mkAppletCrypt ftpstr (strcat fname ".txt") cont (mkAppletUpdateZpFilesName lfiles ftpstr.AFTP_sAppDir);
  );
  0;
}


cbMkAppletCancelBtn(ctrlbtn, p){
let p -> [winstr ftpstr] in
  (
    _TELNETClose ftpstr.AFTP_telnet;
    dsEdWindow winstr;
    set winMkApplet = nil;
  );
  0;
}


cbDestroyExportAppletWin(winstr, ftpstr){
_TELNETClose ftpstr.AFTP_telnet;
  set winMkApplet = nil;
  0;
}


mkApplet(fatherstr, xmlpath, script, w, h){
if winMkApplet != nil then nil else
  (
    let _GETscreenSize -> [sw sh] in
    let [430 405] -> [iw ih] in
    let getFileNameWithoutExt xmlpath -> fname in
    
    let crEdModalDialogWindow _channel fatherstr ((sw / 2) - (iw / 2)) ((sh / 2) - (ih / 2)) iw ih WN_NOSCOL|WN_MENU nil "Export to Web Page" -> winstr in
    let crEdCtrlLabel winstr 10 12 205 20 "Ftp host" nil -> labelhost in
    let crEdCtrlTextLine winstr 220 10 (iw - 230) 20 "" nil EDWIN_RESIZE_MW -> ctrlhost in
    let crEdCtrlLabel winstr 10 37 205 20 "Ftp port" nil -> labelport in
    let crEdCtrlFloat winstr 220 35 60 20 (itof 21) 1.0 65535.0 1.0 0 nil EDWIN_RESIZE_MW -> ctrlport in
    let crEdCtrlLabel winstr 10 62 205 20 "Ftp login" nil -> labellogin in
    let crEdCtrlTextLine winstr 220 60 (iw - 230) 20 "" nil EDWIN_RESIZE_MW -> ctrllogin in
    let crEdCtrlLabel winstr 10 87 205 20 "Ftp password" nil -> labelpass in
    let crEdCtrlTextLine winstr 220 85 (iw - 230) 20 "" ET_BORDER|ET_AHSCROLL|ET_TABFOCUS|ET_PASSWORD EDWIN_RESIZE_MW -> ctrlpass in
    let crEdCtrlLabel winstr 10 112 205 20 "Ftp www root path (ex:/www)" nil -> labelroot in
    let crEdCtrlTextLine winstr 220 110 (iw - 230) 20 "/" nil EDWIN_RESIZE_MW -> ctrlroot in
    let crEdCtrlLabel winstr 10 137 205 20 "Ftp destination directory (ex:project)" nil -> labeldir in
    let crEdCtrlTextLine winstr 220 135 (iw - 230) 20 fname nil EDWIN_RESIZE_MW -> ctrldir in
    let crEdCtrlLabel winstr 10 162 205 20 "Http domain (ex:www.domain.com)" nil -> labelwww in
    let crEdCtrlTextLine winstr 220 160 (iw - 230) 20 "" nil EDWIN_RESIZE_MW -> ctrlwww in
    let crEdCtrlCheck winstr 10 185 (iw - 20) 20 "Insert the application in the web page" EDWIN_RESIZE_MW -> ctrlwebin in
    let crEdCtrlText winstr 10 210 (iw - 20) 150 "" nil EDWIN_RESIZE_MW -> ctrlinfos in
    let crEdCtrlButton winstr 10 (ih - 30) 90 20 "Ok" EDWIN_RESIZE_MW -> ctrlok in
    let crEdCtrlButton winstr (iw - 100) (ih - 30) 90 20 "Cancel" EDWIN_RESIZE_MW -> ctrlcancel in
    let mkFtpSetting [nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil winstr ctrlhost ctrlport ctrllogin ctrlpass ctrlroot ctrldir ctrlwww ctrlwebin ctrlinfos ctrlok ctrlcancel] -> ftpstr in
    (
      set winMkApplet = winstr;
      set ftpstr.AFTP_iWidth = w;
      set ftpstr.AFTP_iHeight = h;
      setEdCtrlButtonCb ctrlok mkfun2 @cbMkAppletOkBtn [xmlpath script ftpstr];
      setEdCtrlButtonCb ctrlcancel mkfun2 @cbMkAppletCancelBtn [winstr ftpstr];
      
      setEdwindowCbDestroy winstr mkfun2 @cbDestroyExportAppletWin ftpstr;
    );
  );
  0;
}
// -- [/filterPKG] --

---